rem ==
rem == CreaPartGPT-SSD-Disk0.txt ==
rem ==
rem == These commands are used in Win10PE with DiskPart to create 4 GPT partitions
rem == for Install of Win10 on a UEFI/GPT-based computer SSD harddisk
rem == In DiskPart use list disk to find disk number and adjust partition sizes and label as necessary.
rem ==
list disk
select disk 0
clean
convert gpt
rem === 1. Recovery partition NTFS 1000 MB ======== Size also Suitable for Win10XPE =====
create partition primary size=1000
format quick fs=ntfs label="Recovery"
set id="de94bba4-06d1-4d40-a16a-bfd50179d6ac"
gpt attributes=0x8000000000000001
rem == 2. EFI Boot partition FAT32 300 MB ==========================
create partition efi size=300
format quick fs=fat32 label="0_EFI"
rem == 3. Microsoft Reserved (MSR) partition =======
create partition msr size=16
rem == 4. Windows 10 partition NTFS ========================
create partition primary
format quick fs=ntfs label="0_W10"
assign
list volume
exit
rem ==
rem == Info https://docs.microsoft.com/en-us/windows-hardware/manufacture/desktop/configure-uefigpt-based-hard-drive-partitions
rem == Info https://docs.microsoft.com/en-us/windows-hardware/manufacture/desktop/configure-biosmbr-based-hard-drive-partitions
rem ==
rem == In admin command window use: DiskPart /s G:\DiskPart\CreaPartGPT-SSD-Disk0.txt
rem ==